class puppet_master
{
        # https repo requires apt-transport-https package already
        # requested in a long generic package list elsewhere.
        apt::source { "passenger":
                comment  => "Passenger (Ruby/Puppet)",
                location => "https://oss-binaries.phusionpassenger.com/apt/passenger",
                release  => $lsbdistcodename,
                repos    => "main",
                # Only accept packages if they have "passenger" in the name.
                pin      => {
                        origin   => "oss-binaries.phusionpassenger.com",
                        priority => "901",
                        packages => "*passenger*",
                },
                key      => {
                        id     => "16378A33A6EF16762922526E561F9B9CAC40B2F7",
                        server => "pgp.mit.edu",
                },
                include  => {
                        src => false,
                        deb => true,
                },
        }

        package { ["libnginx-mod-http-passenger", "passenger"]:
                ensure => installed,
                # Forgot to do this in time: Add a dependency to the repo
                # above to avoid accidentally installing the passenger package
                # from proper Debian first.
        }

        # You don't want the stand-alone daemon to occupy 8140/tcp anymore.
        augeas {
                "puppetmaster-start-nope":
                context => "/files/etc/default/puppet-master",
                changes => "set START no";
        }

        class { "::web":
                sites => [
                        "puppet-master",
                ],
                # Really should be the default..
                php => false,
        }
}